Tera Term マクロ SSH と Telnet の両方に対応したログインマクロを作成するテクニック (Cisco 機器)

; ログイン処理で使用する変数
address ;接続先機器のアドレス
vtypass ;VTYパスワード
username ;ログインユーザ名
userpass ;ログインユーザパスワード

; SSH ログイン用の処理
sprintf2 connectCommand '%s:22 /ssh /2 /auth=password /user=%s /passwd=%s /nosecuritywarning' address username userpass
connect connectCommand

; Telnet ログイン用の処理
sprintf2 connectCommand '%s:23 /nossh /T=1' address
connect connectCommand
wait 'Username:' 'Password:'
if result = 1 then
 sendln username
 wait 'Password:'
 sendln userpass
elseif result = 2 then
 sendln vtypass
endif

connect_protocol = 'ssh' ;接続プロトコル。「ssh」か「telnet」で指定

; connect_protocol が ssh の場合は SSH 接続する
strcompare connect_protocol 'ssh'
if result = 0 then
 ; SSH 接続する処理を記述
endif

; connect_protocol が telnet の場合は Telnet 接続する
strcompare connect_protocol 'telnet'
if result = 0 then
 ; Telnet 接続する処理を記述
endif

; エラー判定用変数の初期化
error_flag = 1 

; SSH or Telnet 接続処理
; SSH or Telnet 接続が成功した後に error_flag = 0 と設定する

; connect_protocol の設定が正しくない場合はマクロを停止
if error_flag = 1 then
 messagebox 'プロトコル設定(connect_protocol)が不正のため処理を中止します' 'エラー'
 end
endif

;;=========================================
;; (1)変数定義パート
;;=========================================
; 接続先機器情報を設定(マクロユーザ編集箇所)
hostname = 'MyRouter' ;ホスト名
address = '10.1.1.1' ;接続先アドレス
vtypass = 'admin' ;VTYパスワード、使用しない場合は変更不要
username = 'admin' ;ユーザ名、使用しない場合は変更不要
userpass = 'admin' ;ユーザパスワード、使用しない場合は変更不要
enablepass = 'admin' ;Enableパスワード
connect_protocol = 'ssh' ;接続プロトコル。「ssh」か「telnet」で指定

; 以下2行は編集不要
sprintf2 prompt_user '^%s.*>' hostname ;ユーザEXECモードのプロンプトを表す正規表現
sprintf2 prompt_privilege '^%s.*#' hostname ;特権EXECモードのプロンプトを表す正規表現

;;=========================================
;; (2)メイン処理パート
;;=========================================
; エラー判定用変数の初期化
error_flag = 1 

; connect_protocol が ssh の場合は SSH 接続する
strcompare connect_protocol 'ssh'
if result = 0 then
 sprintf2 connectCommand '%s:22 /ssh /2 /auth=password /user=%s /passwd=%s /nosecuritywarning' address username userpass
 connect connectCommand
 error_flag = 0 ;エラーフラグの無効化
endif

; connect_protocol が telnet の場合は Telnet 接続する
strcompare connect_protocol 'telnet'
if result = 0 then
 sprintf2 connectCommand '%s:23 /nossh /T=1' address
 connect connectCommand
 wait 'Username:' 'Password:'
 if result = 1 then
  sendln username
  wait 'Password:'
  sendln userpass
 elseif result = 2 then
  sendln vtypass
 endif
 error_flag = 0 ;エラーフラグの無効化
endif

; connect_protocol の設定が正しくない場合はマクロを停止
if error_flag = 1 then
 messagebox 'プロトコル設定(connect_protocol)が不正のため処理を中止します' 'エラー'
 end
endif

; 特権EXECモードに移行
sendln
waitregex prompt_user prompt_privilege
if result = 1 then
 sendln 'enable'
 wait 'Password:'
 sendln enablepass
endif

; 必要ならコマンド実行等の後続の処理を記述